# QMAKE Configuration file
# Copyright (c) 2009, WOSH - Wide Open Smart Home 
# by Alessandro Polo - OpenSmartHome.com
# All rights reserved.
#######################################################
# Revision $Id: GTalkBot.pro 585 2009-09-29 06:10:28Z alex $
#######################################################

CONFIG += console rtti stl exceptions thread moc
QT -= gui

DEPENDPATH += .
INCLUDEPATH += . ../../../

OBJECTS_DIR = ../../../../tmp/GTalkBot

INCLUDEPATH += /usr/include
LIBS += -L/usr/lib
LIBS += -lgloox

HEADERS += GTalkBotImpl.h
SOURCES += GTalkBotImpl.cpp

HEADERS += IGTalkBotListener.h

HEADERS += GTalkBotBundle.h
SOURCES += GTalkBotBundle.cpp


########################################################################
# custom building setting (will override)
!include( ../services.pri ) {
	message( "*****  No custom build options specified. *****" )
	message( "*****  Building Bundles - Services - GTalkBot TEST *****" )
	#CONFIG += make_app_test
} 

#CONFIG += make_lib_static
#CONFIG += make_lib_shared
#CONFIG += make_plugin
#CONFIG += make_app_test
########################################################################


########################################################################
############################################################# LIB STATIC
make_lib_static  {
	message("WOSH Framework - Bundles - Services - GTalkBot - LIB STATIC")

	TEMPLATE = lib
	CONFIG += staticlib
	TARGET = bundleGTalkBot
	DESTDIR = ../../../../lib

}
########################################################################
############################################################# LIB SHARED
make_lib_shared {
	message("WOSH Framework - Bundles - Services - GTalkBot - LIB SHARED")

	TEMPLATE = lib
	TARGET = bundleGTalkBot
	DESTDIR = ../../../../lib

}
########################################################################
################################################################# PLUGIN
make_plugin {
	message("WOSH Framework - Bundles - Services - GTalkBot - PLUGIN")

	TEMPLATE = lib
	TARGET = plugin_GTalkBotBundle
	DESTDIR = ../../../../bin

	SOURCES += plugin_GTalkBotBundle.cpp

}
########################################################################
########################################################################
############################################################### APP TEST
make_app_test {
	message("WOSH Framework - Bundles - Services - GTalkBot - APP TEST")

	TEMPLATE = app
	TARGET = test_GTalkBot
	DESTDIR = ../../../../bin

	LIBS += -L../../../../lib
	LIBS += -lcore

	HEADERS -= GTalkBotBundle.h
	SOURCES -= GTalkBotBundle.cpp

	SOURCES += test_GTalkBot.cpp

}
########################################################################